［Excel 2016/2013/2010/2007］
SUMIF関数、AVERAGEIF関数、COUNTIF関数を使用すると、表の中から条件に合うデータを探して合計、平均、データ数を求められます。ここでは、条件として日付の範囲を指定する方法を紹介します。
［範囲］から［検索条件］を探し、見つかった行の［合計範囲］のデータの合計を求める
=SUMIF(範囲, 検索条件[, 合計範囲])
［範囲］から［条件］を探し、見つかった行の［平均対象範囲］のデータの平均を求める
=AVERAGEIF(範囲, 条件[, 平均対象範囲)
［範囲］から［検索条件］を探してデータ数を求める
=COUNTIF(範囲, 検索条件)
スポンサーリンク
作例…「2017/10/1以降」のデータを集計する
図1の売上記録表の「日付」欄（セルA3～A9）から「2017/10/1以降」（2017/10/1を含む）を検索して、「売上高」欄（セルB3～B9）の数値の合計と平均、およびデータ数を求めます。
「2017/10/1以降」という条件を指定するには、引数［検索条件］に「">=2017/10/1"」と指定します。「2017/10/1」がセルE2に入力されている場合は、「">=" & E2」と指定します。
セルE6 | =SUMIF(A3:A9,">=" & E2,B3:B9)
セルE7 | =AVERAGEIF(A3:A9,">=" & E2,B3:B9)
セルE8 | =COUNTIF(A3:A9,">=" & E2)
図1 「2017/10/1以降」のデータを対象に集計する。
条件の指定例
日付の範囲を条件とするときは、「>」「>=」などの比較演算子と日付を組み合わせて指定します。
| 条件 | 直接指定 | セル参照指定 |
|---|---|---|
| 2017/10/1以降 | ">=2017/10/1" | ">=" & E2 |
| 2017/10/1より後 | ">2017/10/1" | ">" & E2 |
| 2017/10/1以前 | "<=2017/10/1" | "<=" & E2 |
| 2017/10/1より前 | "<2017/10/1" | "<" & E2 |
| 2017/10/1である | "2017/10/1" または "=2017/10/1" | E2 または "=" & E2 |
| 2017/10/1でない | "<>2017/10/1" | "<>" & E2 |
「○から○まで」という期間の条件を指定するには
「○から○まで」のような期間の条件を指定したいときは、複数の条件を指定できるSUMIFS関数、AVERAGEIFS関数、COUNTIFS関数を使います。それぞれSUMIF、AVERAGEIF、COUNTIFの関数名の末尾に複数形を表す「S」を付けた名前になっています。
=SUMIFS(合計対象範囲, 条件範囲1, 条件1[, 条件範囲2, 条件2…])
=AVERAGEIFS(平均対象範囲, 条件範囲1, 条件1[, 条件範囲2, 条件2…])
=COUNTIFS(検索条件範囲1, 検索条件1[,検索条件範囲2, 検索条件2…])
図2では、「日付」が「2017/10/1～2017/10/31」の期間について、「売上高」の合計と平均、およびデータ数を求めています。
セルE6 | =SUMIFS(B3:B9,A3:A9,">=" & E2,A3:A9,"<=" & E3)
セルE7 | =AVERAGEIFS(B3:B9,A3:A9,">=" & E2,A3:A9,"<=" & E3)
セルE8 | =COUNTIFS(A3:A9,">=" & E2,A3:A9,"<=" & E3)
図2 「2017/10/1～2017/10/31」の期間のデータを対象に集計する。
スポンサーリンク