条件に合うデータの合計を求める…SUMIF関数

投稿日:2017年10月17日 更新日:

[Excel 2016/2013/2010/2007]

SUMIF関数を使用すると、表の中から条件に合うデータを探して合計を求められます。

スポンサーリンク

作例…経費帳から「旅費交通費」の合計金額を求める

図1の経費帳の「費目」欄(セルB3~B9)から「旅費交通費」を検索して、「金額」欄(セルC3~C9)の数値を合計します。

SUMIF関数の引数[範囲]に「費目」欄の「B3:B9」、[検索条件]に「旅費交通費」が入力されているセル「E3」、[合計範囲]に「金額」欄の「C3:C9」を指定すると、旅費交通費の金額を合計できます。

[範囲]から[検索条件]を探し、見つかった行の[合計範囲]のデータの合計を求める
=SUMIF(範囲, 検索条件[, 合計範囲])

セルF3 | =SUMIF(B3:B9,E3,C3:C9)

図1 SUMIF関数を使用して、「旅費交通費」の金額を合計する。

関数解説…SUMIF関数

書式

=SUMIF(範囲, 検索条件[, 合計範囲])

範囲]から[検索条件]に一致するデータを探し、見つかった行の[合計範囲]のデータを合計します。

引数

引数 指定 説明
範囲 必須 条件判定の対象となるデータが入力されているセル範囲を指定する
検索条件 必須 条件判定のための条件を指定する
合計範囲 省略可 合計対象の数値が入力されているセル範囲を指定する。省略した場合は[範囲]のデータが合計対象になる

条件の指定例

図2 文字列、数値、日付の条件で集計してみる。

■文字列条件:条件が入力されているセルを指定するか、条件となる文字列を「”」(ダブルクォーテーション)で囲んで入力します。

=SUMIF(C3:C9,F3,D3:D9)
=SUMIF(C3:C9,"旅費交通費",D3:D9)

■数値条件:条件が入力されているセルを指定するか、条件となる数値を直接入力します。

=SUMIF(B3:B9,F4,D3:D9)
=SUMIF(B3:B9,18,D3:D9)

■日付条件:条件が入力されているセルを指定するか、条件となる日付を「"」(ダブルクォーテーション)で囲んで入力するか、DATE関数で「DATE(年,月,日)」のように入力します。

=SUMIF(A3:A9,F5,D3:D9)
=SUMIF(A3:A9,"2017/4/10",D3:D9)
=SUMIF(A3:A9,DATE(2017,4,10),D3:D9)

STEPUP…SUMIF関数をコピーして集計表を作成するには

SUMIF関数を使用して集計表を作成する場合は、数式をコピーしたときに引数[範囲]と[合計範囲]がずれないように、絶対参照(「$A$1」形式)で指定します。引数[検索条件]は相対参照(「A1」形式)で指定して、数式をコピーしたときに適切に条件が変化するようにします。

先頭のセルに入力する数式
セルF3 | =SUMIF($B$3:$B$9,E3,$C$3:$C9)

コピー先の数式
セルF4 | =SUMIF($B$3:$B$9,E4,$C$3:$C9)
セルF5 | =SUMIF($B$3:$B$9,E5,$C$3:$C9)
([検索条件]の「E3」は「E4」「E5」に変化するが、[範囲]と[合計範囲]は変化しない)

図3 引数[範囲]と[合計範囲]を絶対参照、[検索条件]を相対参照で指定すると、数式をコピーするだけで費目ごとの集計表を作成できる。

メモ

セル範囲を絶対参照で指定するには
数式の入力中に、セル範囲B3~B9をドラッグした直後に[F4]キーを押すと、「B3:B9」を自動で絶対参照形式の「$B$3:$B$9」に変更できます。キーボードから直接「$」「B」「$」「3」「:」「$」「B」「$」「9」と入力してもかまいません。

(1)「=SUMIF( 」と入力する。
(2) セルB3~B9をドラッグすると、数式の続きに「B3:B9」が入力される。
(3)[F4]キーを押すと、「B3:B9」が絶対参照「$B$3:$B$9」に変わる。

スポンサーリンク

関連記事

Copyright© Officeのチカラ , 2018 All Rights Reserved.